#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"


#macro isprime(num)
  #if (num = 1)
    #declare ret = 0;
  #else
    #if (num = 2 | num = 3)
      #declare ret = 1;
    #else
      #if (floor(num / 2) * 2 = num)
        #declare ret = 0;
      #else
        #declare n = 3;

        #declare ret = 1;

        #while (n <= sqrt(num))
          #if (floor(num / n) * n = num)
            #declare ret = 0;
          #end
      
          #declare n = n + 2;
        #end
      #end
    #end
  #end

  (ret)
#end


#declare xx = -7;
#declare yy = 2;
#declare num = 1;

#declare XX = -xx;
#declare YY = -yy;

#while (yy > YY)
  #if (isprime(num))
    #declare pig = rgbf<1, 1, 1, .2>;
  #else
    #declare pig = rgbf<132/256, 207/256, 17/256, .2>;
  #end

  sphere {
    <xx, yy, 0>, 0.4
    pigment { pig }
    finish { ambient .3 brilliance .6 reflection .2 crand .02 diffuse .4 }
  }

  #if (xx < XX)
    #declare xx = xx + 1;
  #else
    #declare xx = -XX;
    #declare yy = yy - 1;
  #end

  #declare num = num + 1;
#end


light_source {
  <0, 0, -5>
  color White
}


light_source {
  <0, 5, 5>
  color White
}


camera {
  location <0.4, 3, -12>
  look_at <0, 0, 0>
}